A question from the dark end of the known Europe, any replies
gratefully received, I'm running out of hair.
Has anyone got a DQF-COSY pre-sat 3-9-19 running on a DRX?? I'd
appreciate some tips. What I've got to so far is this:
;cosygsmftp
;avance-version
;2D homonuclear shift correlation
;phase sensitive using TPPI
;using gradient pulses for selection
;with multiple quantum filter according to gradient ratio
;use pulseprogram 'mqsgs1d' for setup
#include <Avance.incl>
#include <Grad.incl>
;;d0=3u
d13=3u
d20=p16+d16+d13
1 ze
2 d1
3 p1 ph1
d0
p0 ph2
d20 UNBLKGRAD
p2 ph4
d13
GRADIENT(cnst21)
d16
p1 ph3
d13
GRADIENT(cnst22)
d16
p28*0.231 ph4
d19*2
p28*0.692 ph4
d19*2
p28*1.462 ph4
d19*2
p28*1.462 ph5
d19*2
p28*0.692 ph5
d19*2
p0*0.231 ph5
46u
GRADIENT(cnst23)
d16
4u BLKGRAMP
go=2 ph31
d1 wr #0 if #0 id0 ip1 zd
lo to 3 times td1
exit
ph1=0 2
ph2=0
ph3=0
ph4=0
ph5=2
ph31=0 2
;pl1 : f1 channel - power level for pulse (default)
;p1 : f1 channel - 90 degree high power pulse
;p0 : f1 channel - x degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p16: homospoil/gradient pulse
;d0 : incremented delay (2D) [3 usec]
;d1 : relaxation delay; 1-5 * T1
;d13: short delay (e.g. to compensate delay line) [3 usec]
;d16: delay for homospoil/gradient recovery
;d20: p16 + d16 + d13
;in0: 1/(2 * SW) = DW
;nd0: 2
;NS: 1 * n
;DS: 16
;td1: number of experiments
;MC2: TPPI
;use gradient program (GRDPROG) : 2sine
;use gradient ratio: cnst21 : cnst22
; 1 : 2 for double quantum filter
; 1 : 3 for triple quantum filter
Which is the best yet. Problem is, two diagonals, suberb water suppression
but no signals! I arrived at this attempt via hacking the appropriate
lumps from the (working):
;mlevgstp19
;avance-version
;homonuclear Hartman-Hahn transfer using MLEV17 sequence
; for mixing
;using two power levels for excitation and spinlock
;phase sensitive using TPPI
;A. Bax & D.G. Davis, J. Magn. Reson. 65, 355-360 (1985)
;water suppression using 3-9-19 pulse sequence with gradients
;M. Piotto, V. Saudek & V. Sklenar, J. Biomol. NMR 2, 661 - 666 (1992)
;V. Sklenar, M. Piotto, R. Leppik $ V. Saudek, J. Magn. Reson.,
; Series A 102, 241 -245 (1993)
#include <Avance.incl>
#include <Grad.incl>
p5=p6*.667
p7=p6*2
;d0=3u
d12=20u
1 ze
2 d1 cw:f2
3 d12 d0:f2
d12 pl1:f1
p1 ph1
d0
d12 pl10:f1
(p17 ph26)
4 (p6 ph22 p7 ph23 p6 ph22)
(p6 ph24 p7 ph25 p6 ph24)
(p6 ph24 p7 ph25 p6 ph24)
(p6 ph22 p7 ph23 p6 ph22)
(p6 ph24 p7 ph25 p6 ph24)
(p6 ph24 p7 ph25 p6 ph24)
(p6 ph22 p7 ph23 p6 ph22)
(p6 ph22 p7 ph23 p6 ph22)
(p6 ph24 p7 ph25 p6 ph24)
(p6 ph22 p7 ph23 p6 ph22)
(p6 ph22 p7 ph23 p6 ph22)
(p6 ph24 p7 ph25 p6 ph24)
(p6 ph22 p7 ph23 p6 ph22)
(p6 ph22 p7 ph23 p6 ph22)
(p6 ph24 p7 ph25 p6 ph24)
(p6 ph24 p7 ph25 p6 ph24)
(p5 ph23)
lo to 4 times l1
(p17 ph26)
50u UNBLKGRAD
GRADIENT(cnst21)
d16
p28*0.231 ph4
d19*2
p28*0.692 ph4
d19*2
p28*1.462 ph4
d19*2
p28*1.462 ph5
d19*2
p28*0.692 ph5
d19*2
p0*0.231 ph5
46u
GRADIENT(cnst22)
d16
4u BLKGRAD
go=2 ph31
d1 wr #0 if #0 id0 ip1 zd
lo to 3 times td1
exit
ph1=0 2
ph4=0 0 1 1 2 2 3 3
ph5=2 2 3 3 0 0 1 1
ph22=3
ph23=0
ph24=1
ph25=2
ph26=0
ph31=0 2 2 0 0 2 2 0
and:
;noesygstp19
;avance-version
;2D homonuclear correlation via dipolar coupling
;dipolar coupling may be due to noe or chemical exchange.
;phase sensitive using TPPI
;water suppression using 3-9-19 pulse sequence with gradients
;M. Piotto, V. Saudek & V. Sklenar, J. Biomol. NMR 2, 661 - 666 (1992)
;V. Sklenar, M. Piotto, R. Leppik $ V. Saudek, J. Magn. Reson.,
; Series A 102, 241 -245 (1993)
#include <Avance.incl>
#include <Grad.incl>
;;d0=3u
;;d12=20u
1 ze
2 d1
3 d12 pl1:f1
p1 ph1
d0
p1 ph2
d8
p1 ph3
d12 pl18:f1
50u UNBLKGRAD
GRADIENT(cnst21)
d16
p28*0.231 ph4
d19*2
p28*0.692 ph4
d19*2
p28*1.462 ph4
d19*2
p28*1.462 ph5
d19*2
p28*0.692 ph5
d19*2
p0*0.231 ph5
46u
GRADIENT(cnst22)
d16
4u BLKGRAD
go=2 ph31
d1 wr #0 if #0 id0 ip1 ze
lo to 3 times td1
exit
ph1=0 2
ph2=0 0 0 0 0 0 0 0 2 2 2 2 2 2 2 2
ph3=0 0 2 2 3 3 1 1
ph4=0
ph5=2
ph31=0 2 2 0 1 3 3 1 2 0 0 2 3 1 1 3
;pl1 : f1 channel - power level for pulse (default)
;pl18: f1 channel - power level for 3-9-19-pulse (watergate)
;p0 : f1 channel - 90 degree pulse at pl18
; use for fine adjustment
;p1 : f1 channel - 90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p16: homospoil/gradient pulse
;p28: f1 channel - 90 degree pulse at pl18
;d0 : incremented delay (2D) [3 usec]
;d1 : relaxation delay; 1-5 * T1
;d8 : mixing time
;d12: delay for power switching [20 usec]
;d16: delay for homospoil/gradient recovery
;d19: delay for binomial water suppression
; d19 = (1/(2*d)), d = distance of next null (in Hz)
;in0: 1/(1 * SW) = 2 * DW
;nd0: 1
;NS: 8 * n
;DS: 16
;td1: number of experiments
;MC2: TPPI
;use gradient program (GRDPROG) : 2sine
;use gradient ratio: cnst21 : cnst22
; 1 : 1
and the working non-presat gradient COSY:
;cosygsmftp
;avance-version
;2D homonuclear shift correlation
;phase sensitive using TPPI
;using gradient pulses for selection
;with multiple quantum filter according to gradient ratio
;use pulseprogram 'mqsgs1d' for setup
#include <Avance.incl>
#include <Grad.incl>
;;d0=3u
;;d13=3u
d20=p16+d16+d13
1 ze
2 d1 LOCKH_OFF
3 p1 ph1
d0
p1 ph2
d20 UNBLKGRAD
p2 ph4
d13
GRADIENT(cnst21)
d16
p1 ph3
d20
p2 ph4
d13
GRADIENT(cnst22)
d16
4u BLKGRAMP
go=2 ph31
d1 wr #0 if #0 id0 ip1 zd LOCKH_OFF
lo to 3 times td1
exit
ph1=0 2
ph2=0
ph3=0
ph4=0
ph31=0 2
;pl1 : f1 channel - power level for pulse (default)
;p1 : f1 channel - 90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p16: homospoil/gradient pulse
;d0 : incremented delay (2D) [3 usec]
;d1 : relaxation delay; 1-5 * T1
;d13: short delay (e.g. to compensate delay line) [3 usec]
;d16: delay for homospoil/gradient recovery
;d20: p16 + d16 + d13
;in0: 1/(2 * SW) = DW
;nd0: 2
;NS: 1 * n
;DS: 16
;td1: number of experiments
;MC2: TPPI
;use gradient program (GRDPROG) : 2sine
;use gradient ratio: cnst21 : cnst22
; 1 : 2 for double quantum filter
; 1 : 3 for triple quantum filter
As far as I can see, the phase cycle is OK, and all should run.
So if anyone can help, or can spot hassles I can't with the first
pulprog above, much appreciated,
Grahame
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Dr. Grahame Harden /
grahame@tardis.oulu.fi 0)%___ /
__/(BMW)===#_
The frozen arctic wasteland is no place to ride / /\\|||L/~~\\
\__/ --- \__/=~~
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~